魔兽7.0猫德实用宏系列整理
2017-11-30 14:41:50 作者:555vs 来源: 浏览次数:0
摘要:部分宏仅限于键位类型与我相似的人使用,如果使用时感觉不合适,可以来回复要求修改
以下宏要求不再回复:
1,能否判断迅捷等buff来释放治疗之触
2,能否卡cd使用A技能其余时间使用B技能
 
7.0会多出神器主动技能,PVP方面还会多个狂怒撕扯(60能量给目标挂斜掠和割裂,吃一切相关加成,潜行可以晕),现在就可以注意调整并习惯键位了。
之前用过我宏的人,最好注意一下,删掉切形态以及回春宏中的狂暴回复...如果点了守护亲和会误放。(狂暴回复机制变了)
 
先放几个新作的宏,其他的慢慢从游戏里搬运。
部分宏仅限于键位类型与我相似的人使用,如果使用时感觉不合适,可以来回复要求修改。
很多宏相关功能可能PVP才有可能用到,按需选用。
 
急奔解减速定身宏:
#showtooltip 急奔 
/cancelform [nostance:0,nostealth] 
/cast 急奔
 
7.0之后,急奔不解减速定身了,不过急奔自身有个效果就是人形时自动变猫而且不占gcd。
于是我想出来这个宏,可以让急奔解减速和定身。
也有缺点,急奔cd时,按会变人形,所以喜欢连按的或者喜欢没事儿就按按急奔的人需要谨慎使用。
 
亲和主要技能整合宏:
 
#showtooltip 
/stopmacro [stealth] 
/cast [@target,help,talent:3/3][@mouseover,help,talent:3/3][talent:3/3]迅捷治愈;[talent:3/1,stance:4]星涌术;[talent:3/1,nostance:4]枭兽形态;[nostance:1]!熊形态 
/cast 狂暴回复
 
 
潜行时不执行宏。
如果点了奶亲和,则对友善目标释放迅捷治愈,如果目标非友善,指向是友善则对指向目标释放,如果均为敌对,则对自己释放。
如果点了咕亲和,按了就变咕,咕形态则释放星涌术。
如果点了熊亲和,按了就变熊,再按释放狂暴回复。

缠绕宏:
 
#showtooltip 纠缠根须 
/stopattack 
/cast [@mouseover,harm][]纠缠根须
 
 
纠缠根须取消平砍,这个等拿到神器,点出流血不破缠绕就很有用了,不然近距离时候平砍就打破了缠绕。
 
冲锋+斜掠+潜行整合宏:
#showtooltip [talent:2/3]野性冲锋;斜掠 
/stopattack [stealth] 
/cast [@target,harm,nostance]猎豹形态   
/cast [nocombat,nostealth,nostance:1/3]!潜行;[@target,exists,harm]斜掠 
/stopattack [stealth] 
/cast 野性冲锋 
/use [nostealth]食火者的瓶子 
/startattack [@target,harm,nostealth]
 
跟以前一样的冲锋斜掠+潜行的整合宏。
脱战且非熊/鹿时,潜行。
远距离时冲锋,近距离时斜掠。
 
闪现+新生宏:
#showtooltip [talent:2/2]野性位移;[talent:2/1]新生;斜掠 
/cast [@target,harm,nostealth]!潜行 
/cast [talent:2/2]野性位移;[talent:2/1]新生;[@target,harm,exists]斜掠
 
 
这个宏是给习惯使用我那个斜掠冲锋整合宏的人准备的。(毕竟野德大多时候都点冲锋
没点冲锋时,按它就是新生或者闪现。点了冲锋就是纯斜掠,这个是为了配合pvp天赋中的扑击,斜掠自带位移,省得浪费冲锋。
 
控制天赋整合宏:
 
#showtooltip [talent:4/1]蛮力猛击;[talent:4/2]群体缠绕;台风 
/stopattack [talent:4/2] 
/cast [@mouseover,harm,talent:4/1][harm,talent:4/1]蛮力猛击;[talent:4/2]群体缠绕;台风 
/cast [@mouseover,talent:4/1,harm][@target,talent:4/1,harm]野性冲锋
 
控制那行天赋的整合宏,加入了优先鼠标指向
 
抓贼+神器宏:
#showtooltip [stealth]斜掠;阿莎曼的狂乱 
/cleartarget [stealth] 
/targetenemyplayer [stealth] 
/stopattack [stealth] 
/cast [@target,exists,stealth]斜掠 
/cast [nostealth]阿莎曼的狂乱 
/stopattack [stealth] 
/script UIErrorsFrame:Clear()
 
原来的抓贼宏,潜行时是斜掠抓最近的敌对玩家,战斗中是精灵火,由于精灵火取消了,现在改为神器主动技能,阿莎曼的狂乱(造成大量伤害,并且获得三个连击点,1分多钟CD)。
 
狂怒撕扯宏(PVP天赋):
 
#showtooltip 狂怒撕扯 
/cast [nocombat,nostealth]!潜行;狂怒撕扯 
/cast 野性冲锋 
/stopattack [stealth] 
/cast [nostance:2]猎豹形态 
/startattack [nostealth]
 
 
满级PVP天赋,狂怒撕扯(60能量,1分钟CD,给目标挂上斜掠和割裂),潜行时释放可以晕人,所以加上了潜行优先级。
当不在战斗中且未潜行时,释放潜行,否则释放狂怒撕扯。
目标不在近战距离就释放野性冲锋。
当前不在猎豹形态则变猫。
 
个人键位适应的撕碎宏:
 
#showtooltip [talent:3/1,stance:4]阳炎术;[stance:1]裂伤;[stance:2]撕碎;[nostance:1/2]猎豹形态 
/cast [talent:3/1,stance:4]阳炎术;[stance:1]裂伤;[nostance:1/2]猎豹形态 
/cast [nocombat,nostealth,nostance:1/3/4]!潜行;[stance:2]撕碎 
/stopattack [stealth] 
/startattack [nostealth]
 
各姿态的输出向技能,非鸟,熊,旅行时,如果可潜行会释放潜行。
猫打撕碎,熊打裂伤,鹌鹑亲和的咕形态打阳炎,非熊非猫非咕则变猫。
 
个人键位适应的月火宏:
 
#showtooltip  
/stopattack [stealth] 
/cast [stealth]撕碎;[stance:1]低吼;[stance:2,talent:1/3][talent:3/1,stance:4]月火术;[stance:2,notalent:1/3]撕碎;[nostance:1/2]猎豹形态 
/stopattack [stealth] 
/stopmacro [nocombat]
 
 
潜行时撕碎(有时候潜行为了递减,不打斜掠,出于个人键位考虑,这个和撕碎宏都是撕碎比较方便)。
熊形态嘲讽,当猫点了咕咕亲和且处于鹌鹑形态时释放月火术,当猫点了月之灵且处于猫形态时释放月火术,当处于猫形态未点月之灵时释放撕碎,非猫非熊非咕则变猫。  
 
影遁相关宏:
影遁飞天:
 
#showtooltip 影遁 
/cast [combat]!影遁 
/cast [nostance:3,nocombat,flyable]!旅行形态;!潜行
 
 
野外跑路宏(影遁和旅行形态两个键位连按不方便或者按得慢的话,这个扔在侧面动作条连点即可,很方便)
影遁飞天,不可飞行的地方则影遁潜行。
 
影遁潜行:
 
#showtooltip 影遁   
/stopattack [stealth] 
/cast !潜行 
/cast [combat]!影遁 
/cast !潜行 
/stopattack [stealth]
 
 
连按,影遁潜行。
现在如果只是为了原地晕人的话,其实只斜掠就够了,因为没有咆哮雕文了,原地没有潜行的必要。
但是如果影遁潜行冲锋偷或者身上无dot,影遁潜行跑路,那这个宏就很方便了。


相关报道:

[关闭] [返回顶部]


  返回首页 | 最新资讯 | 资源下载 | 魔兽图片 | 魔兽单机 | 技术攻略 | 玩家视频
本网站为热爱怀旧WOW的玩家们建立的魔兽世界资料网站,仅供交流和学习使用,非盈利和商用.如有侵权之处,请联系我们
Copyright © 2017 - 2018 PYWOW.COM Corporation, All Rights Reserved

平原魔兽世界私服